cs 2 Norecoil na Faceit przy użyciu cronus zen

Czy takie cos dzialalo by z faceit antycheatem?

Jak ktos sprawdzilby i ogarnal czy to dziala szybciej niz ja 

Cytat

Code:

//-------------------------------------------------------------------------------------------

// ANTIRECOIL adjustable on the fly with SAVE function

//-------------------------------------------------------------------------------------------

// Version: 6.1 - Classic

// Platform: Multi

// Controller: Multi

// Game: All FPS games

// Author: LEX LOST

//------------------------------------------------------------------------------------------

/* *

- Load the script on the CM +

- Turn on the console and enter a game (without enemies, or few enemies)

- Place your character in front of a wall placed at about 10/15 meters (find a wall that leaves the bullet marks while shooting)

- adjusts the antirecoil by increasing it or decreasing it (depending on your weapon's recoil) of one value at a time, 

- till the rose of the bullets on the wall is quite collected

- if needed, adjusts also the horizontal antirecoil if your weapon tends to move sideways while shooting

- save the script.

- Follow the instructions below

* */

//------------------------------------------------------------------------------------------

 

// XBOX INSTRUCTIONS:

 

// ANTIRECOIL (ON by default - Start value: vertical = 30; Horizontal = 0)

// Hold LT and tap UP to increase Antirecoil (+1 each tap on UP, while holding LT)

// Hold LT and tap DOWN to decrease Antirecoil (-1 each tap on DOWN, while holding LT)

// Hold LT and tap RIGHT to compensate to the right (+1 each tap on RIGHT , while holding LT)

// Hold LT and tap LEFT to compensate to the left (+1 each tap on LEFT, while holding LT)

 

// SAVE new values into the CronusMax eeprom: Hold LT and press MENU (or START, for XBOX360 users)

    

//-------------------------------------------------------------------------------------------

// PLAYSTATION INSTRUCTIONS:

 

// ANTIRECOIL (ON by default - Start value: vertical = 30; Horizontal = 0)

// Hold L2 and tap UP to increase Antirecoil (+1 each tap on UP, while holding L2)

// Hold L2 and tap DOWN to decrease Antirecoil (-1 each tap on DOWN, while holding L2)

// Hold L2 and tap RIGHT to compensate to the right(+1 each tap on RIGHT , while holding L2)

// Hold L2 and tap LEFT to compensate to the left (+1 each tap on LEFT, while holding L2)

 

// Save new values into the CronusMax eeprom: Hold L2 and press OPTIONS (or START, for PS3 users)

 

//-------------------------------------------------------------------------------------------

 

//DECLARARATIONS - define

 

define save = 2; // XB1_MENU - PS4_OPTIONS

//-------------------------------------------------------------------------------------------

define Scope_only = TRUE; // if TRUE Antirecoil IS ON only when scoping - if FALSE, is always ON

//-------------------------------------------------------------------------------------------

define UP = 13;     

define DOWN = 14;   

define LEFT = 15; 

define RIGHT = 16;  

//-------------------------------------------------------------------------------------------

 

//VARIABLES - int

 

int recoil_onoff = TRUE; // if TRUE Antirecoil is ON by default - if FALSE, OFF by default

int ANTI_RECOIL;

int ANTI_RECOIL_H;  

int anti_recoil;

int anti_recoil_H;

int AR_Release;

int fire_button;

int scope_button;

 

//-------------------------------------------------------------------------------------------

 

//INITIALIZATION - init

 

init{

 

    if(get_console() == PIO_PS3) {

        fire_button = 3;

        scope_button = 6;

    }else { 

        fire_button = 4;

        scope_button = 7;

    }

 

    ANTI_RECOIL = get_pvar(SPVAR_2, -100, 100, 30);

    ANTI_RECOIL_H = get_pvar(SPVAR_3, -100, 100, 0);

    AR_Release = get_pvar(SPVAR_4, -100, 100, 40);    

} 

 

//-------------------------------------------------------------------------------------------

 

//MAIN BLOCK ROUTINES

 

main {  

        

    if(get_val(scope_button) && event_press(save)){

        combo_run(vibrate);

        set_pvar(SPVAR_2, ANTI_RECOIL);

        set_pvar(SPVAR_3, ANTI_RECOIL_H);

        set_val(save, 0);

    }

    if(get_val(7)){

        if(event_press(UP)){

            ANTI_RECOIL = ANTI_RECOIL+ 1; AR_Release = AR_Release+ 1;

        }

        if(event_press(DOWN)) {

            ANTI_RECOIL = ANTI_RECOIL- 1; AR_Release = AR_Release- 1;

        }

        set_val(UP,0); set_val(DOWN,0);

   

        if(event_press(LEFT)){

            ANTI_RECOIL_H = ANTI_RECOIL_H+ 1;

        }

        if(event_press(RIGHT)) {

            ANTI_RECOIL_H = ANTI_RECOIL_H- 1;

        }

        set_val(LEFT,0); set_val(RIGHT,0);

 

    }

    if(!Scope_only || get_val(scope_button) && get_val(fire_button )) {

        combo_run(AntiRecoil);

    }

 

    if( abs(get_val(10)) > AR_Release || abs(get_val(9)) > AR_Release) {  

        combo_stop (AntiRecoil);

    }

}

//-------------------------------------------------------------------------------------------

 

//COMBO BLOCKS

 

combo vibrate {

    set_rumble(RUMBLE_A, 100);

    wait(300);

    reset_rumble();

    }

 

combo AntiRecoil { // This combo must be the last one

    if(recoil_onoff) {

    anti_recoil = get_val(10) + ANTI_RECOIL;

    if(anti_recoil > 100) anti_recoil = 100;

    set_val(10, anti_recoil);

    anti_recoil_H = get_val(9) + ANTI_RECOIL_H;

    if(anti_recoil_H > 100) anti_recoil_H = 100;

    set_val(9, anti_recoil_H);

    }

}